Add http-parser

net-libs/http-parser/http-parser-2.9.4-r2.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="HTTP request/response parser for C"
+HOMEPAGE="https://github.com/nodejs/http-parser"
+SRC_URI="https://github.com/nodejs/http-parser/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+# 2.9.4 restored ABI compatibility with 2.9.0 but since we failed
+# to set subslot in 2.9.3, we want to provoke another rebuild
+SLOT="0/2.9.4"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x64-macos ~x64-solaris"
+IUSE="static"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-non-x86-test.patch
+)
+
+src_configure() {
+	tc-export CC AR
+}
+
+src_compile() {
+	if use static; then
+		emake PREFIX="${EPREFIX}/usr" LIBDIR="${EPREFIX}/usr/$(get_libdir)" CFLAGS_FAST="${CFLAGS}" package
+	else
+		emake PREFIX="${EPREFIX}/usr" LIBDIR="${EPREFIX}/usr/$(get_libdir)" CFLAGS_FAST="${CFLAGS}" library
+	fi
+}
+
+src_test() {
+	emake CFLAGS_DEBUG="${CFLAGS}" CFLAGS_FAST="${CFLAGS}" test
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" LIBDIR="${EPREFIX}/usr/$(get_libdir)" install
+
+	insinto "${EPREFIX}/usr/$(get_libdir)"
+	doins libhttp_parser.a
+
+	einstalldocs
+}